!?FU1103; [Start of iron chest result Function]

!!VRy1:S1 T4; [Set y1 to random number from 1-5]

!!IF&1000:Q2^You spend all day fishing in the well. Eventually you haul up a rusty old chest.

Do you open it?^;

!!IF&-1000:V2/1; [If player is AI, set flag 2 to true]

!!VRy1&-2:S0; [If chest isn't opened, set y1 to 0]

!!IF&y1=0/1000:M^You toss the unopened chest back down the well where it lands with an incredibly loud {*SPLASH*} at the bottom!^;

[Empty chest: y1=1]
!!IF&y1=1/1000:M^Much to everyone's disappointment, the chest turns out to be empty.^;

[Chest contains gold: y1=2]
!!VRy2&y1=2:S1 T7 *100; [Set y2 to random number from 100 to 800]
!!IF&y1=2/1000:Q1/6/y2/1^Inside the chest you find

{%Y2 Gold Coins!}^;
!!OW&y1=2:R-1/6/dy2; [Give player gold]

[Chest contains resources: y1=3]
!!VRy2&y1=3:S0 T5; [Set y2 to random number from 0 to 5 -- resource type]
!!VRy3&y1=3:S3 T7; [Set y2 to random number from 3 to 8 -- resource amount]
!!IF&y1=3/1000:Q1/y2/y3/1^Inside the chest you find valuable resources!}^;
!!OW&y1=3:R-1/y2/dy3; [Give player resources]

[Chest contains artifact: y1=4]
!!FU1108&y1=4:P; [Set v308 to random artifact number: 7 to 127 excluding tomes, and Angel Wings]
!!HE-1&y1=4:Av308; [Give hero artifact #v308]
!!IF&y1=4/1000:Q2/8/v308/1^Inside the chest you're elated to discover a magical artifact!^;

[Chest contains trap: y1=5]
!!HE-1&y1=5:B0/?z303; [Store hero's name in z303]
!!VRy2&y1=5:S0 T6; [Set y2 to random number from 0 to 6 -- army slot number]
!!VRy3&y1=5:S1 T4; [Set y3 to random number from 1 to 4 -- number of darts]
!!HE-1&y1=5:C0/y2/d0/?y4; [Store # of monsters found in hero's army slot y2 in y4]
!!VRy3&y3>y4:Sy4; [If more darts than monsters, make equal to monsters]
!!HE-1&y1=5:C0/y2/?y5/d0; [Store TYPE of monsters found in hero's army slot y2 in y5]
!!IF&y1=5/y4=0/1000:M^It's a TRAP! Deadly poison darts fly out, but luckily they all miss and nobody is injured.^;
!!VRy6&y1=5:Sy3 *65536 +y5; [Store type/number of monsters for message display purposes in y6]
!!UN&y1=5/y4>0:N3/z304/y5/1; [Store monster name (plural) in z304]
!!IF&y1=5/y4>0/1000:Q1/21/y6/1^It's a TRAP! Deadly poison darts fly out and instantly kill %Y3 of %Z303's loyal %Z304!^;
!!VRy3&y1=5:*-1; [Change y3 into a negative value]
!!HE-1&y1=5/y4>0:C0/y2/d0/dy3; [Remove y3 troops killed by darts]

------------------------------------------------------------------------------------------

!?FU1104; [Start of monster result Function]

!!FU1105:P; [Get monster # Function]
!!VRy1:S1 T6; [Set y1 to random number from 1 to 7 - number of monsters that appear]
!!VRy2:Sy1 *65536 +v300; [Set y2 to monster type/number for message display purposes]
!!IF&1000:Q1/21/y2/1^After spending several lazy hours fishing in the well, you're totally unprepared for what suddenly emerges!^;
!!HE-1:Tv998/v999/v1000/v300/y1; [Start a battle with hero vs y1 of type v300 monsters]